File:Proof-Pythagorean-Theorem.svg

beginfig(1)
    pair A,B,C,H,a,b,c;
    C=(0,0); B=(18cm,0); A=(0cm,10cm);
    marksize=0.9cm;
  
    labeloffset := 12pt;  
    defaultscale:= 35pt/fontsize defaultfont;
  
    H - C = whatever * (B-A) rotated 90;
    H = whatever [B,A];
    draw A--B--C--cycle withpen pencircle scaled 2bp;
    draw C--H;
  
    label.ulft("A", A);
    label.lrt("B", B);
    label.llft("C", C);
    label.top("H", H);
  
    labeloffset := 8pt;
    label.bot("a",1/2[B,C]);
    label.lft("b",1/2[A,C]);
    label.urt("c",1/2[A,B]);
  
    labeloffset := 9pt;
    label.rt("h",1/2[C,H]);
  
    draw ((1,0)--(1,1)--(0,1))
      zscaled (marksize*unitvector((1,0)));
    draw ((-1,0)--(-1,1)--(0,1))
      zscaled (marksize*unitvector(H)) shifted H;
  endfig;
  end

The SVG file was created by running the following command on the input above:

  mptopdf triangle.mp

and using the [http://www.tlhiv.org/MetaPost/tools/mptosvg/ MetaPost to SVG Converter], which basically does the following:

  pstoedit -page 1 -dt -psarg "-r9600x9600" -f sk foo-1.pdf foo-1.sk
  skconvert foo-1.sk foo-1.svg