File:Fibre bundle - animation.gif

From Wikimedia Commons, the free media repository
Jump to navigation Jump to search

Fibre_bundle_-_animation.gif (360 × 323 pixels, file size: 2.52 MB, MIME type: image/gif, looped, 261 frames)

Captions

Captions

Add a one-line explanation of what this file represents

Summary

[edit]
Description
English: Animation making clear how Moebius strip is obtained as a fibre bundle, where base space is a circle and a typical fibre corresponds to a line segment.
Date
Source Own work
Author JozumBjada

Licensing

[edit]
I, the copyright holder of this work, hereby publish it under the following license:
w:en:Creative Commons
attribution share alike
This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.
You are free:
  • to share – to copy, distribute and transmit the work
  • to remix – to adapt the work
Under the following conditions:
  • attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
  • share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

Source

[edit]

This animation was created using Mathematica 10.4.1.0 for Linux x86 (64-bit). Source code follows. 

(* geometry constants *)
r=3; (* radius *)
{circlePos,stripPos}={-5,0};
tubeWidth=0.05;

(* appearance constants *)
{maxRecur,imgResolution}={2,100};
{circleColor,stripColor,fibreColor}={Darker[Green],Red,Blue};
plotRange={{-r-1,r+1},{-r-1,r+1},{-5,2}};
viewPoint={2.876201,-4.651416,1.7582050};

(* from curve make tube or arrow *)
tubePlot[plot_,tubeWidth_:tubeWidth]:=(plot)/.Line[pts_,rest___]:>Tube[pts,tubeWidth,rest]
tubeArrowPlot[plot_,tubeWidth_:tubeWidth]:=(plot)/.Line[pts_,rest___]:>Arrow@Tube[pts,tubeWidth,rest]

(* circle *)
circle[v_,z_:circlePos,r_:r]:={r Cos[v],r Sin[v],z}
ring=tubePlot@ParametricPlot3D[circle[u,stripPos],{u,0,2\[Pi]},PlotStyle->circleColor];

(* moebius strip *)
moebius[u_,v_]:={(r+u Cos[v/2]) Cos[v],(r+u Cos[v/2]) Sin[v],stripPos+u Sin[v/2]};
moebiusStrip=ParametricPlot3D[moebius[u,v],{u,-1,1},{v,0,2\[Pi]},PlotStyle->{stripColor,Opacity[0.8]},MaxRecursion->maxRecur,Mesh->None];

(* brush of fibres *)
brushFun=moebius[u,#]&/@Range[0,2\[Pi],0.1];
brush=ParametricPlot3D[brushFun,{u,-1,1},PlotStyle->fibreColor];

(* fibre *)
fibre=tubePlot@ParametricPlot3D[moebius[u,0],{u,-1,1},PlotStyle->{fibreColor,Opacity[0.8]},MaxRecursion->maxRecur,Mesh->None];

(* individual stages of animation... *)
ringGeneration={tubePlot@ParametricPlot3D[circle[u,stripPos],{u,0,#},PlotStyle->circleColor]}&/@Range[0.01,2\[Pi],0.1];
fibreGeneration={ring,tubeArrowPlot@ParametricPlot3D[moebius[u,0],{u,0,#},PlotStyle->fibreColor],tubePlot@ParametricPlot3D[moebius[u,0],{u,0,-#},PlotStyle->fibreColor]}&/@Range[0.01,1,0.05];
delayAfterFibreGeneration=Table[Last@fibreGeneration,5];
stripGeneration={ring,ParametricPlot3D[moebius[u,v],{u,-1,1},{v,0,#},PlotStyle->{stripColor,Opacity[0.8]},MaxRecursion->maxRecur,Mesh->None],tubeArrowPlot@ParametricPlot3D[moebius[u,#],{u,-1,1},PlotStyle->{fibreColor,Opacity[0.8]},MaxRecursion->maxRecur,Mesh->None]}&/@Range[0.01,2\[Pi]+0.05,0.1];
delayAfterStripGeneration=Table[Last@stripGeneration,5];
brushGeneration={moebiusStrip,fibre,ring,ParametricPlot3D[brushFun,{u,0,#},PlotStyle->fibreColor],ParametricPlot3D[brushFun,{u,0,-#},PlotStyle->fibreColor]}&/@Range[0.01,1,0.05];
ringMovement={moebiusStrip,brush,ring/.Tube[x___]:>Translate[Tube[x],{0,0,-#}]}&/@Range[0,4.2,0.1];
fibreMovement={moebiusStrip,brush,Last@ringMovement,Graphics3D[{fibreColor,Translate[Rotate[Tube[Line[{{0,0,0},{2,0,0}}],tubeWidth],\[Pi]/2 #,{0,1,0},{0,0,0}],#({-r,-r,stripPos+1}-moebius[0,0])+moebius[0,0]]}]}&/@Range[0,1,0.05];
ringMovement=Join[#,{fibre}]&/@ringMovement;
delayAfterFibreMovement=Table[Last@fibreMovement,20];

(* put everything together and rasterize *)
animation=Join[ringGeneration,fibreGeneration,delayAfterFibreGeneration,stripGeneration,delayAfterStripGeneration,brushGeneration,ringMovement,fibreMovement,delayAfterFibreMovement];
animation=Show[#,Boxed->False,Axes->False,ViewPoint->viewPoint,PlotRange->plotRange]&/@animation;
animation=Rasterize[#,ImageResolution->imgResolution]&/@animation;

(* export as gif animation and show *)
Export[NotebookDirectory[]<>"fibre_bundle_animation.gif",animation]
ListAnimate[animation]

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current21:09, 20 June 2016Thumbnail for version as of 21:09, 20 June 2016360 × 323 (2.52 MB)JozumBjada (talk | contribs)Arrows added. A circle going deeper.
12:13, 11 June 2016Thumbnail for version as of 12:13, 11 June 2016350 × 350 (1.31 MB)JozumBjada (talk | contribs)User created page with UploadWizard

You cannot overwrite this file.

There are no pages that use this file.

File usage on other wikis

The following other wikis use this file:

Metadata

This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.

Retrieved from "https://commons.wikimedia.org/w/index.php?title=File:Fibre_bundle_-_animation.gif&oldid=467010003"