File:Black and white ISO speed.svg
Original file (SVG file, nominally 640 × 480 pixels, file size: 10 KB)
Captions
Summary
[edit]DescriptionBlack and white ISO speed.svg |
English: Method for determining the speed of a black and white film as per ISO 6. Français : Détermination de la sensibilité d'un film noir et blanc conformément à ISO 6. |
Date | |
Source | Own work |
Author | Edgar Bonet |
Other versions | ISO6speedMethod.png: |
This file is derived from ISO6speedMethod.png by JeffConrad. I recreated the image using Gnuplot in order to have a vector image free of English text suitable for use in the French Wikipedia. It uses decimal commas in labels 1–3, but it is trivial to change them to decimal points if needed.
Gnuplot source
[edit]Warning: This source contains the following non-ASCII characters: U+2212 (minus sign, in xtics) and U+0394 (capital delta, in labels 1–3).
#!/usr/bin/gnuplot
# Method for determining the speed of a black and white film
# as per ISO 6.
f(x) = Dmin + (Dmax-Dmin)/(1+1/x+1/x**3)
D(x) = f(10**((x-offset)/stretch))
Dmin = 0.2
Dmax = 2.7
offset = -1.161
stretch = 2.775
x_m = -2.38851
y_m = Dmin + 0.1
x_n = x_m + 1.3
y_n = y_m + 0.8
set terminal svg size 640 480 enhanced dashed
set output 'Black_and_white_ISO_speed.svg'
set xlabel "log H"
set xrange [-3:1]
set xtics ("−3" -3, "−2" -2, "−1" -1, 0, 1)
set ylabel "D" offset 1.5, 0
set yrange [0:2.5]
set ytics 1
unset key
set label 1 "Δ log H = 1,3" at x_m + 0.65, 1.5 center
set label 2 "ΔD = 0,8" at -0.66, 0.7 center
set label 3 "ΔD = 0,1" at -1.27, 0.46 center
set label 4 "m" at x_m - 0.08, y_m + 0.09 center
set label 5 "n" at x_n - 0.08, y_n + 0.09 center
set label 6 "D_{min}" at -0.4, Dmin center
set label 7 "log H_m" at x_m, -0.12 center
set label 8 "D_m" at -3.16, y_m + 0.02 center
set arrow 1 from x_m, y_m + 0.05 to x_m, 1.6 nohead
set arrow 2 from x_n, y_n + 0.05 to x_n, 1.6 nohead
set arrow 3 from -2.10, 1.5 to x_m, 1.5 filled
set arrow 4 from -1.37, 1.5 to x_n, 1.5 filled
set arrow 5 from x_m + 0.10, y_m to -0.7, y_m nohead
set arrow 6 from x_n + 0.05, y_n to -0.7, y_n nohead
set arrow 7 from -0.8, 0.62 to -0.8, y_m filled
set arrow 8 from -0.8, 0.78 to -0.8, y_n filled
set arrow 9 from -3, Dmin to -0.55, Dmin lt 7 lc rgbcolor "black" nohead
set arrow 10 from -1.3, Dmin to -1.3, Dmin + 0.1 nohead
set arrow 11 from -1.3, Dmin - 0.01 to -1.3, Dmin size 0.07, 15 filled
set arrow 12 from -1.3, Dmin + 0.11 to -1.3, Dmin + 0.1 size 0.07, 15 filled
set arrow 13 from x_m, 0 to x_m, y_m-0.05 nohead
set arrow 14 from -3, y_m to x_m - 0.10, y_m nohead
plot D(x) lw 2 lc rgbcolor "#00007e", \
'-' w points ls 7 lc rgbcolor "#000000"
-2.38851 0.3
-1.08851 1.1
e
Licensing
[edit]- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 09:17, 24 October 2013 | 640 × 480 (10 KB) | Edgar.bonet (talk | contribs) | User created page with UploadWizard |
You cannot overwrite this file.
File usage on Commons
The following page uses this file:
File usage on other wikis
The following other wikis use this file:
- Usage on fr.wikipedia.org
Metadata
This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.
Image title | Produced by GNUPLOT 4.4 patchlevel 3 |
---|---|
Width | 640 |
Height | 480 |